/*
 * CylonEyes
 * ---------
 * Implement a Cylon-like eye scanning display using two 74HC595s, 16 LEDs
 * Optionally, to get a more incadescent-like "fade" of light, insert a 
 * low-pass filter with a transistor and big capacitor between 595s and LEDs.
 *
 * Much of this code stolen from: http://www.arduino.cc/en/Tutorial/ShiftOut
 *
 * Created 27 November 2006
 * copyleft 2006 Tod E. Kurt <tod@todbot.com>
 * http://hackingroomba.com/
 */
 
int dataPin  = 7;  // Pin connected to DS    of 74HC595
int clockPin = 6;  // Pin connected to SH_CP of 74HC595
int latchPin = 5;  // Pin connected to ST_CP of 74HC595

int t2 = 30;
int t1 = 80;
int t0 = 250;

void setup() {
  //set pins to output because they are addressed in the main loop
  pinMode(latchPin, OUTPUT);

  //function that blinks all the LEDs
  //gets passed the number of blinks and the pause time
  blinkAll16(1,1000);
}

void loop() {
  //blinkAll16(2,1000);
  for(int i=0; i<4; i++) {
    delay(t0);
    //delay(t1);
    //blinkAll16(1,delayt2);  //charge capacitors  
    for (int j = 0; j < 15; j++) {
      digitalWrite(latchPin, 0);
      shiftOut16(dataPin, clockPin, 1<<(j+1) | 1<<j);  
      digitalWrite(latchPin, 1);
      delay(t1);
      digitalWrite(latchPin, 0);
      shiftOut16(dataPin, clockPin, 1<<j);
      digitalWrite(latchPin, 1);
      delay(t2);
    }
    //delay(t1);
    //blinkAll16(1,delayt2);  //charge capacitors
    // light each pin one by one using a function A
    for (int j = 15; j >=0; j--) {
      digitalWrite(latchPin, 0);
      shiftOut16(dataPin, clockPin, 1<<(j-1) | 1<<j);  
      digitalWrite(latchPin, 1);
      delay(t1);
      digitalWrite(latchPin, 0);
      shiftOut16(dataPin, clockPin, 1<<j);
      digitalWrite(latchPin, 1);
      delay(t2);
    }
  }
}

void lightShift16Pin(int p) { 
  shiftOut16(dataPin, clockPin, 1 << p);
}


void shiftOut16(int myDataPin, int myClockPin, int myDataOut) {
  // This shifts 16 bits out MSB first, 
  // on the rising edge clockPin, clock idles low
  pinMode(myClockPin, OUTPUT);
  pinMode(myDataPin, OUTPUT);
  //clear everything out just in case
  digitalWrite(myDataPin, 0);
  digitalWrite(myClockPin, 0);

  for (int i=15; i>=0; i--)  {
    digitalWrite(myClockPin, 0);
    int pinState = (myDataOut & (1<<i)) ? 1:0;
    digitalWrite(myDataPin, pinState);
    //register shifts bits on upstroke of clock pin  
    digitalWrite(myClockPin, 1);
    //zero the data pin after shift to prevent bleed through
    digitalWrite(myDataPin, 0);
  }
  //stop shifting
  digitalWrite(myClockPin, 0);
}


//blinks both registers based on the number of times you want to 
//blink "n" and the pause between them "d"
//starts with a moment of darkness to make sure the first blink
//has its full visual effect.
void blinkAll16(int n, int d) {
  digitalWrite(latchPin, 0);
  shiftOut16(dataPin, clockPin, 0x0000);
  digitalWrite(latchPin, 1);
  delay(100);
  for (int x = 0; x < n; x++) {
    digitalWrite(latchPin, 0);
    shiftOut16(dataPin, clockPin, 0xffff);
    digitalWrite(latchPin, 1);
    delay(d);
    digitalWrite(latchPin, 0);
    shiftOut16(dataPin, clockPin, 0x0000);
    digitalWrite(latchPin, 1);
    delay(d);
  }
}